mirror of
https://github.com/firebase/firebase-ios-sdk
synced 2026-11-11 22:55:59 +05:45
Gil
77f92cd2c6
* Fix previously unknown warnings These become visible once flags are handled uniformly across all Firestore targets in an upcoming build change. * Stop using built-in CMake Framework support CMake has built-in support for building Framework bundles (briefly: bundles of libraries, associated headers, and resources) but this doesn't work well for our needs. 1. In CMake 3.5.1 (our earliest supported CMake version) it doesn't copy headers properly at build time. 2. Even up to CMake 3.15.5, CMake doesn't handle link-line multiplicity correctly. CMake passes the static library location within the framework and this seems to cause the linker to mishandle Objective-C metaclass information resulting in duplicate symbols. Building with `-framework` flags works correctly. Previously we partially worked around the latter problem by building some frameworks as shared instead of static frameworks, but this is problematic because this mode of operation isn't actually intended and is unsupported as far as the rest of Firebase is concerned. This turned out to be fragile though and while refactoring libraries this workaround broke. Rather than piling on additional workarounds, this change converts the frameworks to simple library targets and emulates framework imports through include paths. Additionally, this starts refactoring our cmake helper functions to make them more like built-in functions. This makes it possible to freely use different CMake features that were made difficult by trying to wrap everything up in a single CMake command. * style.sh generated changes * Review feedback * More review feedback
104 lines
2.7 KiB
Plaintext
104 lines
2.7 KiB
Plaintext
/*
|
|
* Copyright 2017 Google
|
|
*
|
|
* Licensed under the Apache License, Version 2.0 (the "License");
|
|
* you may not use this file except in compliance with the License.
|
|
* You may obtain a copy of the License at
|
|
*
|
|
* http://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS,
|
|
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
* See the License for the specific language governing permissions and
|
|
* limitations under the License.
|
|
*/
|
|
|
|
#import "FIRFieldPath.h"
|
|
|
|
#include <functional>
|
|
#include <string>
|
|
#include <utility>
|
|
#include <vector>
|
|
|
|
#import "Firestore/Source/API/FIRFieldPath+Internal.h"
|
|
|
|
#include "Firestore/core/src/firebase/firestore/model/field_path.h"
|
|
#include "Firestore/core/src/firebase/firestore/util/exception.h"
|
|
#include "Firestore/core/src/firebase/firestore/util/hashing.h"
|
|
#include "Firestore/core/src/firebase/firestore/util/string_apple.h"
|
|
|
|
namespace util = firebase::firestore::util;
|
|
using firebase::firestore::model::FieldPath;
|
|
using firebase::firestore::util::ThrowInvalidArgument;
|
|
|
|
NS_ASSUME_NONNULL_BEGIN
|
|
|
|
@interface FIRFieldPath () {
|
|
/** Internal field path representation */
|
|
firebase::firestore::model::FieldPath _internalValue;
|
|
}
|
|
|
|
@end
|
|
|
|
@implementation FIRFieldPath
|
|
|
|
- (instancetype)initWithFields:(NSArray<NSString *> *)fieldNames {
|
|
if (fieldNames.count == 0) {
|
|
ThrowInvalidArgument("Invalid field path. Provided names must not be empty.");
|
|
}
|
|
|
|
std::vector<std::string> converted;
|
|
converted.reserve(fieldNames.count);
|
|
for (NSString *fieldName in fieldNames) {
|
|
converted.emplace_back(util::MakeString(fieldName));
|
|
}
|
|
|
|
return [self initPrivate:FieldPath::FromSegments(std::move(converted))];
|
|
}
|
|
|
|
+ (instancetype)documentID {
|
|
return [[FIRFieldPath alloc] initPrivate:FieldPath::KeyFieldPath()];
|
|
}
|
|
|
|
- (instancetype)initPrivate:(FieldPath)fieldPath {
|
|
if (self = [super init]) {
|
|
_internalValue = std::move(fieldPath);
|
|
}
|
|
return self;
|
|
}
|
|
|
|
+ (instancetype)pathWithDotSeparatedString:(NSString *)path {
|
|
return
|
|
[[FIRFieldPath alloc] initPrivate:FieldPath::FromDotSeparatedString(util::MakeString(path))];
|
|
}
|
|
|
|
- (id)copyWithZone:(NSZone *__nullable)zone {
|
|
(void)zone;
|
|
return [[[self class] alloc] initPrivate:_internalValue];
|
|
}
|
|
|
|
- (BOOL)isEqual:(nullable id)object {
|
|
if (self == object) {
|
|
return YES;
|
|
}
|
|
|
|
if (![object isKindOfClass:[FIRFieldPath class]]) {
|
|
return NO;
|
|
}
|
|
|
|
return _internalValue == ((FIRFieldPath *)object)->_internalValue;
|
|
}
|
|
|
|
- (NSUInteger)hash {
|
|
return util::Hash(_internalValue);
|
|
}
|
|
|
|
- (const firebase::firestore::model::FieldPath &)internalValue {
|
|
return _internalValue;
|
|
}
|
|
|
|
@end
|
|
|
|
NS_ASSUME_NONNULL_END
|