mirror of
https://github.com/firebase/firebase-ios-sdk
synced 2026-11-10 22:45:59 +05:45
Gil
39d8252300
This reimplements our comparison functions as C++ Comparators and then provides compatibility shims for interoperating with existing Objective-C usage. A few specialized comparators aren't suitable for porting but only have a single usage (e.g. CompareBytes for comparing NSData * instances). In these cases I've moved them into the caller. * Use int32_t for typeof(ID) in FSTDocumentReference * Migrate callers of FSTComparison.h to Objective-C++ * Port comparison to C++ * Migrate usages of FSTComparison.h to C++ equivalents * Remove FSTComparison
87 lines
2.4 KiB
Plaintext
87 lines
2.4 KiB
Plaintext
/*
|
|
* Copyright 2017 Google
|
|
*
|
|
* Licensed under the Apache License, Version 2.0 (the "License");
|
|
* you may not use this file except in compliance with the License.
|
|
* You may obtain a copy of the License at
|
|
*
|
|
* http://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS,
|
|
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
* See the License for the specific language governing permissions and
|
|
* limitations under the License.
|
|
*/
|
|
|
|
#import "Firestore/Source/Local/FSTDocumentReference.h"
|
|
|
|
#include "Firestore/core/src/firebase/firestore/util/comparison.h"
|
|
|
|
#import "Firestore/Source/Model/FSTDocumentKey.h"
|
|
|
|
using firebase::firestore::util::WrapCompare;
|
|
|
|
NS_ASSUME_NONNULL_BEGIN
|
|
|
|
@implementation FSTDocumentReference
|
|
|
|
- (instancetype)initWithKey:(FSTDocumentKey *)key ID:(int32_t)ID {
|
|
self = [super init];
|
|
if (self) {
|
|
_key = key;
|
|
_ID = ID;
|
|
}
|
|
return self;
|
|
}
|
|
|
|
- (BOOL)isEqual:(id)other {
|
|
if (other == self) return YES;
|
|
if (![[other class] isEqual:[self class]]) return NO;
|
|
|
|
FSTDocumentReference *reference = (FSTDocumentReference *)other;
|
|
|
|
return [self.key isEqualToKey:reference.key] && self.ID == reference.ID;
|
|
}
|
|
|
|
- (NSUInteger)hash {
|
|
NSUInteger result = [self.key hash];
|
|
result = result * 31u + self.ID;
|
|
return result;
|
|
}
|
|
|
|
- (NSString *)description {
|
|
return [NSString stringWithFormat:@"<FSTDocumentReference: key=%@, ID=%d>", self.key, self.ID];
|
|
}
|
|
|
|
- (id)copyWithZone:(nullable NSZone *)zone {
|
|
// FSTDocumentReference is immutable
|
|
return self;
|
|
}
|
|
|
|
@end
|
|
|
|
#pragma mark Comparators
|
|
|
|
/** Sorts document references by key then ID. */
|
|
const NSComparator FSTDocumentReferenceComparatorByKey =
|
|
^NSComparisonResult(FSTDocumentReference *left, FSTDocumentReference *right) {
|
|
NSComparisonResult result = FSTDocumentKeyComparator(left.key, right.key);
|
|
if (result != NSOrderedSame) {
|
|
return result;
|
|
}
|
|
return WrapCompare<int32_t>(left.ID, right.ID);
|
|
};
|
|
|
|
/** Sorts document references by ID then key. */
|
|
const NSComparator FSTDocumentReferenceComparatorByID =
|
|
^NSComparisonResult(FSTDocumentReference *left, FSTDocumentReference *right) {
|
|
NSComparisonResult result = WrapCompare<int32_t>(left.ID, right.ID);
|
|
if (result != NSOrderedSame) {
|
|
return result;
|
|
}
|
|
return FSTDocumentKeyComparator(left.key, right.key);
|
|
};
|
|
|
|
NS_ASSUME_NONNULL_END
|